Lote de números: par, impar, factorial, primo, múltiplo y divisores

Programa en Pseudocódigo para resolver el siguiente problema:
Dado un lote de numeros positivos se pide calcular:
 a) Si el numero introducido es par calcular su factorial.
 b) Si el numero introducido es impar verificar si es primo.
 c) Si el numero introducido es par y multiplo de 5 mostrar la suma de sus divisores.

Proceso lote_par_impar_multiplo
    Escribir "Introducir la cantidad de numeros: "
    Repetir
        leer n
    Hasta Que n>0 & n = trunc(n)
    Escribir "Ahora introdusca los numeros: "
    Para j<-1 Hasta n Con Paso 1 Hacer
        Leer x
        Si x % 2 = 0 Entonces
            f<-1
            Para i<-1 Hasta x Con Paso 1 Hacer
                f<-f*i
            FinPara
            Escribir x," Es par y su factorial es: ",f
            Si x % 5 = 0 Entonces
                s<-0
                Escribir "Ademas es multiplo de 5"
                Para l<-1 Hasta x Con Paso 1 Hacer
                    Si x % l = 0 Entonces
                        s<-s+l
                    FinSi
                FinPara
                Escribir "Y la suma de sus divisores es: ", s
            FinSi
        Sino
            c<-0
            Para k<-1 Hasta x Con Paso 1 Hacer
                Si x % k = 0 Entonces
                    c<-c+1
                FinSi
            FinPara
            Si c=2 Entonces
                Escribir x," Es impar y si es primo"
            Sino
                Escribir x," Es impar y no es primo"
            FinSi
        FinSi
    FinPara
FinProceso